本文件已封存並已停止維護。
建議的版本

@@ERROR (Transact-SQL)

SQL Server 2005

傳回最後執行的 Transact-SQL 陳述式的錯誤號碼。

主題連結圖示 Transact-SQL 語法慣例

複製 

@@ERROR

integer

如果先前的 Transact-SQL 陳述式沒有發現任何錯誤，便傳回 0。

如果先前的陳述式發現錯誤，便傳回錯誤號碼。如果錯誤是 sys.messages 目錄檢視中的錯誤之一，@@ERROR 會包含這項錯誤在 sys.messages.message_id 資料行中的值。您可以在 sys.messages 中檢視 @@ERROR 錯誤號碼的相關聯文字。

由於執行每個陳述式時，都會清除再重設 @@ERROR，因此，請在陳述式之後，立即檢查它，或將它儲存在稍後能夠檢查的本機變數中。

SQL Server 2005 Database Engine 導入了 TRY...CATCH 建構來處理錯誤。TRY...CATCH 建構也支援其他會傳回 @@ERROR 以外之錯誤資訊的系統函數 (ERROR_LINE、ERROR_MESSAGE、ERROR_PROCEDURE、ERROR_SEVERITY 和 ERROR_STATE)。TRY...CATCH 也支援 ERROR_NUMBER 函數，ERROR_NUMBER 函數並不限於在緊接於產生錯誤的陳述式之後的陳述式中傳回錯誤號碼。如需詳細資訊，請參閱＜TRY...CATCH (Transact-SQL)＞。

A. 利用 @@ERROR 來偵測特定錯誤

這個範例利用 @@ERROR 來檢查 UPDATE 陳述式的 CHECK 條件約束違規 (錯誤號碼 547)。

複製 
USE AdventureWorks;
GO
UPDATE HumanResources.Employee 
    SET PayFrequency = 4
    WHERE NationalIDNumber = 615389812;
IF @@ERROR = 547
    PRINT N'A check constraint violation occurred.';
GO

B. 利用 @@ERROR 有條件地結束程序

這個範例中的 IF...ELSE 陳述式會測試預存程序中，在 INSERT 陳述式之後的 @@ERROR。@@ERROR 變數的值決定了傳給呼叫端程式來指出程序成功或失敗的傳回碼。

複製 
USE AdventureWorks;
GO
-- Drop the procedure if it already exists.
IF OBJECT_ID(N'HumanResources.usp_DeleteCandidate', N'P')
             IS NOT NULL
    DROP PROCEDURE HumanResources.usp_DeleteCandidate;
GO
-- Create the procedure.
CREATE PROCEDURE HumanResources.usp_DeleteCandidate 
    @CandidateID INT
AS
-- Execute the DELETE statement.
DELETE FROM HumanResources.JobCandidate
    WHERE JobCandidateID = @CandidateID;
-- Test the error value.
IF @@ERROR <> 0 
    BEGIN
        -- Return 99 to the calling program to indicate failure.
        PRINT N'An error occurred deleting the candidate information.';
        RETURN 99;
    END
ELSE
    BEGIN
        -- Return 0 to the calling program to indicate success.
        PRINT N'The job candidate has been deleted.';
        RETURN 0;
    END;
GO

C. 搭配 @@ROWCOUNT 來使用 @@ERROR

這個範例搭配 @@ROWCOUNT 來使用 @@ERROR 驗證 UPDATE 陳述式的作業。@@ERROR 的值用來針對任何錯誤指示來進行檢查，@@ROWCOUNT 則用來確保更新已成功套用至資料表的資料列。

複製 
USE AdventureWorks;
GO
IF OBJECT_ID(N'Purchasing.usp_ChangePurchaseOrderHeader',N'P')
             IS NOT NULL
   DROP PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader;
GO
CREATE PROCEDURE Purchasing.usp_ChangePurchaseOrderHeader
    @PurchaseOrderID INT, 
    @EmployeeID INT
AS
-- Declare variables used in error checking.
DECLARE @ErrorVar INT, 
    @RowCountVar INT;

-- Execute the UPDATE statement.
UPDATE PurchaseOrderHeader 
    SET EmployeeID = @EmployeeID 
    WHERE PurchaseOrderID = @PurchaseOrderID;

-- Save the @@ERROR and @@ROWCOUNT values in local 
-- variables before they are cleared.
SELECT @ErrorVar = @@ERROR, 
    @RowCountVar = @@ROWCOUNT;

-- Check for errors. If an invalid @EmployeeID was specified
-- the UPDATE statement returns a foreign-key violation error #547.
IF @ErrorVar <> 0
    BEGIN
        IF @ErrorVar = 547
            BEGIN
                PRINT N'ERROR: Invalid ID specified for new employee.';
                RETURN 1;
            END
        ELSE
            BEGIN
                PRINT N'ERROR: error '
                    + RTRIM(CAST(@ErrorVar AS NVARCHAR(10)))
                    + N' occurred.';
                RETURN 2;
            END
    END

-- Check the row count. @RowCountVar is set to 0 
-- if an invalid @PurchaseOrderID was specified.
IF @RowCountVar = 0
    BEGIN
        PRINT 'Warning: The EmployeeID specified is not valid';
        RETURN 1;
    END
ELSE
    BEGIN
        PRINT 'Purchase order updated with the new employee';
        RETURN 0;
    END;
GO
顯示: